Membuat Grafis Bumi 3D

Untuk membuat grafis 3D, kita akan menggunakan library Flare3D. Library Flare 3D dapat anda peroleh dari folder lib pada folder installasi flare. Untuk menambahkan library tersebut ke dalam aplikasi, ikuti langkah berikut

1. Buatlah sebuah file baru dengan tipe Actionscript 3.0
2. Klik menu File > Actionscript Setting
3. Klik Add new path selanjutnya klik Browse to SWC file
4. Buka folder installasi flare3D, pada folder lib pilih file flare3D.swc
5. Tekan OK, dan library Flare3D telah terinstall pada aplikasi yang sedang kita buat

Anda juga membutuhkan sebuah file yang akan digunakan sebagai Material dari model 3D bumi yang akan dibuat. File ini bisa anda dapatkan dengan mencari di google dengan keyword "earth 3D material". Sebagai contoh digunakan peta bumi seperti pada gambar berikut dengan nama file "peta bumi.jpg" dan diletakkan pada folder yang sama dengan file FLA.

File tersebut tidak perlu kita import ke stage/library, karena dapat ditambahkan dari luar aplikasi.
Selanjutnya klik frame 1 layer 1, dan ketikan kode berikut :

import flare.basic.*;
import flare.core.*;
import flare.events.*;
import flare.materials.*;
import flare.materials.filters.*;

import flash.display.*;
import flash.events.Event;
import flare.primitives.Sphere;

var scene:Scene3D;
var texture:Texture3D;
var material:Shader3D;

var bumi:Pivot3D;

function setup():void{
	scene = new Viewer3D(this);
	scene.camera.setPosition(10, 0, 10);
	scene.camera.lookAt(0,0,0);
	scene.autoResize = true;
	scene.addEventListener(Scene3D.COMPLETE_EVENT, mulai);
	//texture
	texture = scene.addTextureFromFile("peta bumi.jpg");
	material = new Shader3D("petabumi");
	material.filters.push(new TextureMapFilter(texture));
	material.build();
	//membuat bumi
	bumi = new Sphere("bumi");
	bumi.setMaterial(material);
	scene.addChild(bumi);
	scene.pause()
}

function mulai(e:Event):void{
	scene.addEventListener(Scene3D.UPDATE_EVENT, rotasi);
	scene.resume();
}

function rotasi(e:Event):void{
	bumi.rotateY(-0.5);
}

setup();

Jalankan aplikasi dengan menekan tombol Ctrl+Enter.Apabila tidak ada kesalahan pengaturan, maka akan didapatkan animasi 3D bumi berotasi.

File sumber : FLA Adobe Animate 2017 - Animasi 3D Bumi Berotasi

Video tutorial :

Share ( Ayo Berbagi )

Leave me a comment

untuk pertanyaan lebih baik di email langsung ke wandah [at] wandah [dot] com agar cepat direspon